DOPAMINERGIC(D2) RECEPTOR BINDING ACTIVITY (4)

                   PREFIX n: <https://nap.nprod.net/>
 CONSTRUCT {
     ?pharmacy n:has_pharmacology <https://nap.nprod.net/pharmacology/4>.
     ?pharmacy a n:pharmacy;
               n:has_worktype ?worktype;
               n:has_organism ?organism;
               n:has_participant ?compound;
               n:has_pharmacology ?pharmacology;
               n:number ?number.
     ?pharmacology n:name ?pharmacologyName.
     ?organism n:familyname ?organism_family_name.
     ?organism n:genusname ?organism_genus_name.
     ?organism n:speciesname ?organism_species_name.
     ?compound a n:compound.
     ?compound n:name ?compoundName.
} 
 WHERE {
   ?pharmacy n:has_pharmacology <https://nap.nprod.net/pharmacology/4>.
   ?pharmacy a n:pharmacy;
             n:has_worktype ?worktype.
               
   OPTIONAL { ?pharmacy n:has_organism ?organism. }
   OPTIONAL { ?pharmacy n:has_pharmacology ?pharmacology.
              ?pharmacology n:name ?pharmacologyName. }
   OPTIONAL { ?pharmacy n:has_participant ?compound. 
              ?compound a n:compound; 
                        n:name ?compoundName.  }
   OPTIONAL { ?organism n:familyname ?organism_family_name. }
   OPTIONAL { ?organism n:genusname ?organism_genus_name. }
   OPTIONAL { ?organism n:speciesname ?organism_species_name. }
   OPTIONAL { ?organism n:organismclass ?organism_class. }
   OPTIONAL { ?pharmacy n:number ?number. }
   
 } LIMIT 10000